home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / wizard.arc / WIZARD.BAS (.txt)
Encoding:
GW-BASIC  |  1980-01-01  |  23.9 KB  |  527 lines
  1. 5  KEY OFF:CLEAR
  2. 10  RANDOMIZE VAL(RIGHT$(TIME$,2))
  3. 20  DIM C$(34),I$(34),R$(4),W$(8),E$(8),AM$(4)
  4. 30  DIM C(3,4),T(8),O(3),R(3):PRINT CHR$(12);"CREATING ARRAYS"
  5. 50  DEF FND(Q)=Q*64+X*8+Y+36887:DEF FNE(Q)=Q+100*(Q>99)
  6. 60  Y$=CHR$(13)+"** ANSWER YES OR NO  "+CHR$(13)
  7. 70  DEF FNA(Q)=1+INT(RND(8)*Q):DEF FNB(Q)=Q+8*((Q=9)-(Q=0))
  8. 80  Q=RND(8):RESTORE:FOR Q=1 TO 34:READ C$(Q),I$(Q):NEXT Q
  9. 90  FOR Q=36960 TO 37472:POKE Q,101:NEXT Q:FOR Q=1 TO 8:READ W$(Q),E$(Q):NEXT Q
  10. 100  FOR Q=1 TO 4:READ R$(Q):NEXT Q:
  11. 103  FOR Q=1 TO 4:READ AM$(Q):NEXT Q:
  12. 105  DEF FNC(Q)=-Q*(Q<19)-18*(Q>18)
  13. 110  PRINT CHR$(12):GOSUB 3270:PRINT TAB(27) "THE WIZARD'S CASTLE":PRINT:GOSUB 3270
  14. 120  PRINT "Copyright (C) 1980 by Joseph Power":PRINT
  15. 121  PRINT "Edited and Translated for the IBM Personal Computer by Brad Mead":PRINT
  16. 130  PRINT "Last revised - 4/15/82":PRINT
  17. 135  PRINT "Modified by Tom Sweeney          6/8/82"
  18. 140  PRINT:PRINT:PRINT "Please be Patient - ";:X=1:Y=4
  19. 150  POKE FND(1),2:PRINT "IN";:FOR Z=1 TO 7:FOR Q1=1 TO 2:Q=104:GOSUB 3200
  20. 160  POKE FND(Z+1),103:NEXT Q1:NEXT Z:PRINT "I";
  21. 170  FOR Z=1 TO 8:FOR Q=113 TO 124:GOSUB 3200:NEXT Q:FOR Q1=1 TO 3
  22. 180  FOR Q=105 TO 112:GOSUB 3200:NEXT Q:Q=125:GOSUB 3200:NEXT Q1:READ O$:PRINT O$;:NEXT Z
  23. 190  FOR Q=126 TO 133:Z=FNA(8):GOSUB 3200:NEXT Q:PRINT "G";
  24. 200  Q=101:FOR A=1 TO 3:Z=FNA(8):GOSUB 3200:C(A,1)=X:C(A,2)=Y:C(A,3)=Z:C(A,4)=0
  25. 210  READ O$:PRINT O$;:NEXT A:PRINT "S";:RC=0:ST=2:DX=14
  26. 220  Q=112+FNA(12):Z=FNA(8):GOSUB 3200:R(1)=X:R(2)=Y:R(3)=Z
  27. 230  Q=109:Z=FNA(8):GOSUB 3200:O(1)=X:O(2)=Y:O(3)=Z:PRINT "TLE"
  28. 240  BF=0:OT=8:AV=0:HT=0:T=1:VF=0:LF=0:TC=0:GP=60:RF=0:OF=0:BL=0:H=0
  29. 250  IQ=8:SX=0:FOR Q=1 TO 8:T(Q)=0:NEXT Q:GOSUB 4220:PRINT CHR$(12);"ALL RIGHT, BOLD ONE, YOUR ADVENTURE BEGINS!"
  30. 255  PRINT "BUT FIRST, I MUST FIND OUT WHO AND WHAT YOU ARE."
  31. 256  PRINT:PRINT "TO SAVE TIME WHEN ANSWERING QUESTIONS,":PRINT "TYPE ONLY THE FIRST LETTER OF THE WORD."
  32. 257  PRINT:PRINT:PRINT
  33. 260  PRINT:PRINT "YOU MAY BE AN ELF, DWARF, MAN, OR HOBBIT":GOSUB 3280
  34. 270  FOR Q=1 TO 4:IF LEFT$(R$(Q),1)=O$ THEN RC=Q:ST=ST+2*Q:DX=DX-2*Q
  35. 280  NEXT Q:PRINT:OT=OT+4*(RC=1):IF RC>0 THEN R$(3)="HUMAN":GOTO 300
  36. 290  PRINT "** THAT WAS INCORRECT, PLEASE TYPE E, D, M, OR H.":GOTO 260
  37. 300  PRINT:PRINT "SEX ";:GOSUB 3290:IF O$="M" THEN SX=1:GOTO 320
  38. 310  IF O$<>"F" THEN PRINT:PRINT "** CUTE ";R$(RC);", REAL CUTE. TRY M OR F":GOTO 300
  39. 320  PRINT CHR$(12):PRINT "OK ";R$(RC);", YOU HAVE THESE STATISTICS:":PRINT
  40. 330  PRINT "STRENGTH= ";ST;"  INTELLIGENCE= ";IQ;" DEXTERITY= ";DX:PRINT
  41. 340  PRINT "AND ";OT;" OTHER POINTS TO ALLOCATE AS YOU WISH.":PRINT
  42. 350  Z$="INTELLIGENCE ":GOSUB 3300:IQ=IQ+Q:IF OT=0 THEN 370
  43. 360  Z$="STRENGTH ":GOSUB 3300:ST=ST+Q:IF OT THEN Z$="DEXTERITY ":GOSUB 3300:DX=DX+Q
  44. 370  CLS:IF OT>0 THEN PRINT "STUPID ";R$(RC);", YOU DIDN'T ALLOCATE ALL YOUR OTHER POINTS!":PRINT "IF YOU WANT TO GET THROUGH THIS ALIVE, YOU BETTER SHAPE UP!":PRINT
  45. 375  PRINT "OK, ";R$(RC);", YOU HAVE 60 GOLD PIECES (GP'S)":PRINT
  46. 380  Z$="ARMOR":GOSUB 3390:AV=0:WV=0:FL=0:WC=0
  47. 390  PRINT "PLATE <30>  CHAINMAIL <20>  LEATHER <10>  NOTHING <0>"
  48. 400  GOSUB 3280:IF O$="N" THEN 440
  49. 410  AV=-3*(O$="P")-2*(O$="C")-(O$="L"):IF AV>0 THEN 440
  50. 420  PRINT:PRINT"** ARE YOU A ";R$(RC);" OR ";C$(FNA(12)+12);
  51. 430  PRINT " ? TYPE S,C,L OR N":PRINT:GOTO 380
  52. 440  AH=AV*7:GP=GP-AV*10:PRINT CHR$(12)
  53. 450  PRINT:PRINT"OK, BOLD ";R$(RC);", YOU HAVE ";GP;" GP'S LEFT":PRINT
  54. 460  Z$="WEAPONS":GOSUB 3390
  55. 470  PRINT "SWORD <30>  MACE <20>  DAGGER <10>  NOTHING <0>":GOSUB 3280:IF O$="N" THEN 500
  56. 480  WV=-3*(O$="S")-2*(O$="M")-(O$="D"):IF WV>0 THEN 500
  57. 490  PRINT:PRINT "** YOU HAVE THE IQ OF A KOBOLD!  TYPE S, M, D, OR N":PRINT:GOTO 460
  58. 500  GP=GP-WV*10:PRINT CHR$(12):IF GP<20 THEN 540
  59. 510  PRINT "WANT TO BUY A LAMP FOR 20 GP'S ";:GOSUB 3290
  60. 520  IF O$="Y" THEN LF=1:GP=GP-20:GOTO 540
  61. 530  IF O$<>"N" THEN PRINT:PRINT Y$:PRINT:GOTO 510
  62. 540  PRINT CHR$(12):IF GP<1 THEN Q=0:GOTO 600
  63. 550  PRINT:PRINT"OK, ";R$(RC);", YOU HAVE ";GP;" GOLD PIECES LEFT":PRINT
  64. 560  INPUT "FLARES COST 1 GP EACH, HOW MANY DO YOU WANT ";O$:IF O$="" THEN GOSUB 3333:PRINT: GOTO 560
  65. 570  Q=VAL(O$):PRINT:IF Q>0 OR ASC(O$)=48 THEN 590
  66. 580  PRINT "** IF YOU DON'T WANT ANY JUST TYPE 0 (ZERO)":PRINT:GOTO 560
  67. 590  IF Q>GP THEN PRINT "** YOU CAN ONLY AFFORD ";GP:PRINT:GOTO 560
  68. 600  FL=FL+Q:GP=GP-Q:PRINT CHR$(12):X=1:Y=4:Z=1
  69. 610  PRINT "OK ";R$(RC);", YOU ENTER THE CASTLE AND BEGIN."
  70. 615  PRINT:PRINT"IF YOU NEED INFORMATION, TYPE ";CHR$(34);"?";CHR$(34);" OR ";CHR$(34);"HELP";CHR$(34):PRINT:GOTO 1670
  71. 620  T=T+1:IF RF+OF>0 THEN 690
  72. 630  IF C(1,4)>T(1) THEN T+T+1
  73. 640  IF C(2,4)>T(3) THEN GP=GP-FNA(5):IF GP<0 THEN GP=0
  74. 650  IF C(3,4)<=T(5) THEN 690
  75. 660  A=X:B=Y:C=Z:X=FNA(8):Y=FNA(8):Z=FNA(8)
  76. 670  POKE FND(Z),FNE(PEEK(FND(Z)))+100:X=A:Y=B:Z=C
  77. 680  IF PEEK(FND(Z))=1 THEN FOR Q=1 TO 3:C(Q,4)=-(C(Q,1)=X)*(C(Q,2)=Y)*(C(Q,3)=Z):NEXT Q
  78. 690  IF FNA(5)>1 THEN 790
  79. 700  PRINT:PRINT "YOU ";:Q=FNA(7)+BL:IF Q>7 THEN Q=4
  80. 710  ON Q GOSUB 750,730,740,720,760,770,780:GOTO 790
  81. 720  PRINT "STEPPED ON A FROG":RETURN
  82. 730  PRINT "HEAR ";MID$("A SCREAM FOOTSTEPSA WUMPUS THUNDER",FNA(4)*9-8,9):RETURN
  83. 740  PRINT "SNEEZED":RETURN
  84. 750  PRINT "SEE A BAT FLY BY":RETURN
  85. 760  PRINT "SMELL ";C$(12+FNA(13));" FRYING":RETURN
  86. 770  PRINT "FEEL LIKE YOU ARE BEING WATCHED":RETURN
  87. 780  PRINT "ARE PLAYING WIZARD'S CASTLE":RETURN
  88. 790  IF BL+T(4)=2 THEN PRINT:PRINT C$(29);" CURES YOUR BLINDNESS":BL=0
  89. 800  IF BF+T(6)=2 THEN PRINT:PRINT C$(31);" DISSOLVES THE BOOK":BF=0
  90. 810  PRINT:PRINT:PRINT:INPUT "YOUR MOVE ";O$:IF O$="" THEN GOSUB 3333:GOTO 810:ELSE O$=LEFT$(O$,2): IF O$="DR" OR O$="dr" THEN 1180
  91. 815  O$=LEFT$(O$,1):IF ASC(O$)>90 THEN O$=CHR$(ASC(O$)-32)
  92. 820  IF O$="N"THEN 940
  93. 830  IF (O$="S") OR (O$="W") OR (O$="E") THEN 950
  94. 840  IF O$="U" THEN 970
  95. 850  IF O$="D" THEN 990
  96. 860  IF O$="M" THEN 1010
  97. 870  IF O$="F" THEN ON 1+BL GOTO 1070,1010
  98. 880  IF O$="L" THEN ON 1+BL GOTO 1110,1010
  99. 890  IF O$="O" THEN 1310
  100. 900  IF O$="G" THEN ON 1+BL GOTO 1480,1010
  101. 910  IF O$="T" THEN PRINT:ON 1+RF GOTO 1590,1600
  102. 920  IF O$="Q" THEN 1640
  103. 925  IF O$="H" OR O$="?" THEN GOSUB 5000: CLS: GOTO 1670
  104. 930  PRINT:PRINT"** STUPID ";R$(RC);"  THAT WASN'T A VALID COMMAND":GOTO 620
  105. 940  IF PEEK(FND(Z))=2 THEN 2900
  106. 950  X=X+(O$="N")-(O$="S"): Y=Y+(O$="W")-(O$="E")
  107. 960  X=FNB(X):Y=FNB(Y):GOTO 1670
  108. 970  IF PEEK(FND(Z))=3 THEN Z=Z-1:GOTO 1670
  109. 980  Z$="UP":GOTO 1000
  110. 990  Z$="DOWN":IF PEEK(FND(Z))=4 THEN Z=Z+1:GOTO 1670
  111. 1000  PRINT:PRINT"** OH ";R$(RC);", NO STAIRS GOING ";Z$;" IN HERE":GOTO 620
  112. 1010  IF BL=1 THEN PRINT:PRINT"** YOU CAN'T SEE ANYTHING, DUMB ";R$(RC):GOTO 620
  113. 1020  PRINT:PRINT:A=X:B=Y:FOR X=1 TO 8:FOR Y=1 TO 8:Q=PEEK(FND(Z)):IF Q>99 THEN Q=34
  114. 1030  IF X=A AND Y=B THEN PRINT "<";I$(Q);">";:GOTO 1050
  115. 1040  PRINT " ";I$(Q);" ";
  116. 1050  NEXT Y:PRINT:NEXT X:X=A:Y=B:GOTO 1100
  117. 1070  IF FL=0 THEN PRINT:PRINT "HEY BRIGHT ONE, YOU'RE OUT OF FLARES":GOTO 620
  118. 1080  PRINT:PRINT:FL=FL-1:A=X:B=Y:Q1=A-1:Q2=B:PRINT "    ";:GOSUB 1090:PRINT:PRINT"  ";:Q1=A:FOR Q2=B-1 TO B+1:GOSUB 1090:NEXT:PRINT:PRINT"  ";:Q1=A+1:Q2=B:PRINT"  ";:GOSUB 1090:PRINT: PRINT:X=A:Y=B: GOTO 1100
  119. 1090  X=FNB(Q1):Y=FNB(Q2):Q=FNE(PEEK(FND(Z))):POKE FND(Z),Q:PRINT I$(Q);" ";:RETURN
  120. 1100  GOSUB 3400: GOTO 620
  121. 1110  IF LF=0 THEN PRINT:PRINT "YOU DON'T HAVE A LAMP, ";R$(RC):GOTO 620
  122. 1120  PRINT:PRINT"WHERE DO YOU SHINE THE LAMP (N,S,E, OR W) ";:GOSUB 3290
  123. 1130  A=X:B=Y:X=FNB(X+(O$="N")-(O$="S")):Y=FNB(Y+(O$="W")-(O$="E"))
  124. 1140  IF A-X+B-Y=0 THEN PRINT:PRINT "TURKEY!  THAT'S NOT A DIRECTION!":GOTO 620
  125. 1150  PRINT:PRINT"THE LAMP SHINES INTO (";X;",";Y;") LEVEL ";Z:PRINT
  126. 1160  POKE FND(Z),FNE(PEEK(FND(Z))):PRINT "THERE YOU WILL FIND ";C$(PEEK(FND(Z)))
  127. 1170  X=A:Y=B:GOTO 620
  128. 1180  IF PEEK (FND(Z))<>5 THEN PRINT:PRINT "** IF YOU WANT A DRINK, FIND A POOL":GOTO 620
  129. 1190  Q=FNA(8):PRINT:PRINT"YOU TAKE A DRINK AND ";:IF Q<7 THEN PRINT "FEEL ";
  130. 1200  ON Q GOTO 1210,1220,1230,1240,1250,1260,1270,1290
  131. 1210  ST=FNC(ST+FNA(3)):PRINT "STRONGER":GOTO 620
  132. 1220  ST=ST-FNA(3):PRINT"WEAKER":ON 1-(ST<1) GOTO 620,2840
  133. 1230  IQ=FNC(IQ+FNA(3)):PRINT "SMARTER":GOTO 620
  134. 1240  IQ=IQ-FNA(3):PRINT "DUMBER":ON 1-(IQ<1) GOTO 620,2840
  135. 1250  DX=FNC(DX+FNA(3)):PRINT "NIMBLER":GOTO 620
  136. 1260  DX=DX-FNA(3):PRINT "CLUMSIER": ON 1-(DX<1) GOTO 620,2840
  137. 1270  Q=FNA(4):IF Q=RC THEN 1270
  138. 1280  RC=Q:PRINT "BECOME A ";R$(RC):GOTO 620
  139. 1290  SX=1-SX:PRINT "TURN INTO A ";:IF SX=0 THEN PRINT "FE";
  140. 1300  PRINT "MALE ";R$(RC):GOTO 620
  141. 1310  IF PEEK(FND(Z))=6 THEN PRINT:PRINT "YOU OPEN THE CHEST AND":PRINT:GOTO 1430
  142. 1320  IF PEEK(FND(Z))=12 THEN PRINT "YOU OPEN THE BOOK AND":PRINT:GOTO 1340
  143. 1330  PRINT:PRINT"** THE ONLY THING YOU OPENED WAS YOUR BIG MOUTH":GOTO 620
  144. 1340  ON FNA(6) GOTO 1350,1360,1370,1380,1390,1400
  145. 1350  PRINT "FLASH! OH NO! YOU ARE NOW A BLIND ";R$(RC):BL=1:GOTO 1420
  146. 1360  PRINT "IT'S ANOTHER VOLUME OF ZOT'S POETRY! - YEECH!":GOTO 1420
  147. 1370  PRINT "IT'S AN OLD COPY OF PLAY";R$(FNA(4)):GOTO 1420
  148. 1380  PRINT "ITS A MANUAL OF DEXTERITY!":DX=FNC(DX+FNA(6)):GOTO 1420
  149. 1390  PRINT "IT'S A MANUAL OF STRENGTH!":ST=FNC(ST+FNA(6)):GOTO 1420
  150. 1400  PRINT "THE BOOK STICKS TO YOUR HANDS -":PRINT
  151. 1410  PRINT "NOW YOU CAN'T DRAW YOUR WEAPON!":BF=1
  152. 1420  POKE FND(Z),1:GOTO 620
  153. 1430  ON FNA(4) GOTO 1440,1450,1460,1450
  154. 1440  PRINT "KABOOM! IT EXPLODES":Q=FNA(6):GOSUB 2800:ON 1-(ST<1) GOTO 1420,2840
  155. 1450  Q=FNA(1000):PRINT"FIND ";Q;" GOLD PIECES":GP=GP+Q:GOTO 1420
  156. 1460  PRINT "GAS! YOU STAGGER FROM THE ROOM"
  157. 1470  POKE FND(Z),1:T=T+20:O$=MID$("NSEW",FNA(4),1):GOTO 950
  158. 1480  IF PEEK(FND(Z))<>11 THEN PRINT:PRINT "** NO ORB - NO GAZE":GOTO 620
  159. 1490  PRINT:PRINT"YOU SEE ";:ON FNA(6)GOTO 1500,1510,1530,1540,1560,1580
  160. 1500  PRINT "YOURSELF IN A BLOODY HEAP":ST=ST-FNA(4):ON 1-(ST<1) GOTO 620,2840
  161. 1510  PRINT "YOURSELF DRINKING FROM A POOL AND BECOMING ";C$(12+FNA(13))
  162. 1520  GOTO 620
  163. 1530  PRINT C$(12+FNA(13));" GAZING BACK AT YOU":GOTO 620
  164. 1540  A=X:B=Y:C=Z:X=FNA(8):Y=FNA(8):Z=FNA(8):Q=FNE(PEEK(FND(Z))):POKE FND(Z),Q
  165. 1550  PRINT C$(Q);" AT (";X;",";Y;") LEVEL ";Z:X=A:Y=B:Z=C:GOTO 620
  166. 1560  A=FNA(8):B=FNA(8):C=FNA(8):IF FNA(8)<4 THEN A=O(1):B=O(2):C=O(3)
  167. 1570  PRINT "THE ORB OF ZOT AT (";A;",";B;") LEVEL ";C:GOTO 620
  168. 1580  PRINT "A SOAP OPERA RERUN":GOTO 620
  169. 1590  IF RF=0 THEN PRINT "** YOU CAN'T TELEPORT WITHOUT THE RUNESTAFF!":GOTO 620
  170. 1600  Z$="X-COORDINATE (1=FAR NORTH 8=FAR SOUTH) ":GOSUB 3350:X=Q
  171. 1610  Z$="Y-COORDINATE (1=FAR WEST  8=FAR EAST ) ":GOSUB 3350:Y=Q
  172. 1620  Z$="LEVEL        (1=TOP       8=BOTTOM   ) ":GOSUB 3350:Z=Q:O$="T"
  173. 1630  IF O$="T" GOTO 1670
  174. 1640  PRINT:PRINT"DO YOU REALLY WANT TO QUIT ";:GOSUB 3290:PRINT
  175. 1650  IF O$<>"Y" THEN PRINT "THEN DON'T SAY YOU DO":GOTO 620
  176. 1660  PRINT:PRINT:GOTO 2940
  177. 1670  PRINT:IF BL=0 THEN GOSUB 3400:PRINT
  178. 1680  PRINT "ST= ";ST;" IQ= ";IQ;" DX= ";DX;" FLARES= ";FL;" GP'S= ";GP
  179. 1690  PRINT:PRINT W$(WV+1);" / ";W$(AV+5);:IF LF=1 THEN PRINT " / A LAMP";
  180. 1700  PRINT:PRINT:WC=0:Q=FNE(PEEK(FND(Z))):POKE FND(Z),Q:Z$="YOU HAVE "
  181. 1710  PRINT "HERE YOU FIND ";C$(Q):IF (Q<7) OR (Q=11) OR (Q=12) THEN 620
  182. 1720  IF Q=7 THEN GP=FNA(500)+GP:PRINT:PRINT Z$;GP:GOTO 1420
  183. 1730  IF Q=8 THEN FL=FL+FNA(5):PRINT:PRINT Z$;FL:GOTO 1420
  184. 1740  IF Q>9 THEN 1770
  185. 1750  PRINT:IF (O(1)=X)AND(O(2)=Y)AND(O(3)=Z) THEN ON 1-(O$="T") GOTO 950,3050
  186. 1760  X=FNA(8):Y=FNA(8):Z=FNA(8):GOTO 1670
  187. 1770  IF Q=10 THEN Z=FNB(Z+1):GOTO 1670
  188. 1780  IF Q>25 AND Q<34 THEN PRINT:PRINT"IT'S NOW YOURS":T(Q-25)=1:TC=TC+1:GOTO 1420
  189. 1790  A=PEEK(FND(Z))-12:WC=0:IF (A<13) OR (VF=1) THEN 2300
  190. 1800  PRINT "YOU MAY TRADE WITH, ATTACK, OR IGNORE THE VENDOR"
  191. 1810  GOSUB 3280:IF O$="I" THEN 620
  192. 1820  IF O$="A" THEN VF=1:PRINT:PRINT "YOU'LL BE SORRY YOU DID THAT":GOTO 2300
  193. 1830  IF O$<>"T" THEN PRINT:PRINT"** WRONG, ";R$(RC);"; TRY AGAIN":GOTO 1800
  194. 1840  PRINT:FOR Q=1 TO 8:A=FNA(Q*1500):IF T(Q)=0 THEN 1880
  195. 1850  PRINT:PRINT "DO YOU WANT TO SELL ";C$(Q+25);" FOR ";A;" GP'S";
  196. 1860  GOSUB 3290:IF O$="Y" THEN TC=TC-1:T(Q)=0:GP=GP+A:GOTO 1880
  197. 1870  IF O$<>"N" THEN PRINT Y$:GOTO 1850
  198. 1880  NEXT Q
  199. 1890  IF GP<1000 THEN PRINT:PRINT "YOU'RE TOO POOR TO TRADE, ";R$(RC):GOTO 620
  200. 1900  IF GP<1250 THEN 2130
  201. 1910  PRINT:PRINT"OK, ";R$(RC);", YOU HAVE ";GP;" GOLD PIECES AND ";W$(AV+5);:IF AV>0 THEN PRINT " ARMOR IN ";AM$(1+INT(AH/(AV*2)));" CONDITION":ELSE PRINT:
  202. 1920  PRINT:Z$="ARMOR":GOSUB 3390:PRINT "NOTHING<0> LEATHER <1250> ";
  203. 1930  IF GP>1499 THEN PRINT "CHAINMAIL <1500> ";:IF GP>1999 THEN PRINT "PLATE <2000>";
  204. 1940  PRINT:GOSUB 3280:PRINT:IF O$="N" THEN 2010
  205. 1950  IF O$="L" THEN GP=GP-1250:AV=1:AH=7:GOTO 2010
  206. 1960  IF O$="C" AND GP<1500 THEN PRINT "** YOU HAVEN'T GOT THAT MUCH CASH":GOTO 1920
  207. 1970  IF O$="C" THEN GP=GP-1500:AV=2:AH=14:GOTO 2010
  208. 1980  IF O$="P" AND GP<2000 THEN PRINT "** YOU CAN"T AFFORD THE PLATE ARMOR":GOTO 1920
  209. 1990  IF O$="P" THEN GP=GP-2000:AV=3:AH=21:GOTO 2010
  210. 2000  PRINT:PRINT"** DON`T WASTE MY TIME! MAKE A SELECTION":GOTO 1940
  211. 2010  IF GP<1250 THEN 2130
  212. 2020  PRINT:PRINT"YOU HAVE ";GP;" GP'S LEFT WITH ";W$(WV+1);" IN HAND":PRINT
  213. 2030  PRINT:Z$="WEAPON":GOSUB 3390:PRINT"NOTHING<0> DAGGER <1250> ";
  214. 2040  IF GP>1499 THEN PRINT "MACE<1500> ";:IF GP>1999 THEN PRINT"SWORD<2000>";
  215. 2050  PRINT:GOSUB 3280:PRINT:IF O$="N" THEN 2130
  216. 2060  IF O$="D" THEN GP=GP-1250:WV=1:GOTO 2130
  217. 2070  IF O$="M" AND GP<1500 THEN PRINT "** SORRY SIR, I DON"T GIVE CREDIT":GOTO 2030
  218. 2080  IF O$="M" THEN GP=GP-1500:WV=2:GOTO 2130
  219. 2090  IF O$="S" AND GP<2000 THEN PRINT "** DUNGEON EXPRESS CARD - ";
  220. 2100  IF O$="S" AND GP<2000 THEN PRINT "YOU LEFT HOME WITHOUT IT!":GOTO 2030
  221. 2110  IF O$="S" THEN GP=GP-2000:WV=3:GOTO 2130
  222. 2120  PRINT "** TRY MAKING A SELECTION":GOTO 2050
  223. 2130  IF GP<1000 THEN 620
  224. 2140  Z$="STRENGTH":GOSUB 3370:IF O$<>"Y" THEN 2160
  225. 2150  GP=GP-1000:ST=FNC(ST+FNA(6)):Q=ST:GOSUB 3380:GOTO 2130
  226. 2160  IF O$<>"N" THEN PRINT Y$:GOTO 2140
  227. 2170  IF GP<1000 THEN 620
  228. 2180  Z$="INTELLIGENCE":GOSUB 3370:IF O$<>"Y" THEN 2200
  229. 2190  GP=GP-1000:IQ=FNC(IQ+FNA(6)):Q=IQ:GOSUB 3380:GOTO 2170
  230. 2200  IF O$<>"N" THEN PRINT Y$:GOTO 2180
  231. 2210  IF GP<1000 THEN 620
  232. 2220  Z$="DEXTERITY":GOSUB 3370:IF O$<>"Y" THEN 2240
  233. 2230  GP=GP-1000:DX=FNC(DX+FNA(6)):Q=DX:GOSUB 3380:GOTO 2210
  234. 2240  IF O$<>"N" THEN PRINT Y$:GOTO 2220
  235. 2250  IF (GP<1000) OR (LF=1) THEN 620
  236. 2260  PRINT:PRINT"WANT A LAMP FOR 1000 GP'S";:GOSUB 3290:IF O$<>"Y" THEN 2280
  237. 2270  GP=GP-1000:LF=1:PRINT:PRINT"IT'S GUARANTEED TO OUTLIVE YOU!":GOTO 620
  238. 2280  IF O$<>"N" THEN PRINT Y$:GOTO 2260
  239. 2290  GOTO 620
  240. 2300  Q1=1+INT(A/2):Q2=A+2:Q3=1
  241. 2310  IF (C(1,4)>T(1)) OR (BL=1) OR (DX<FNA(9)+FNA(9)) THEN 2690
  242. 2320  PRINT:PRINT:PRINT"YOU'RE FACING ";C$(A+12):PRINT:PRINT "YOU MAY ATTACK OR RETREAT";
  243. 2330  IF Q3=1 THEN PRINT ", OR BRIBE";:IF IQ>14 THEN PRINT", OR CAST A SPELL";
  244. 2340  PRINT:PRINT:PRINT "YOUR STRENGTH IS ";ST;" AND DEXTERITY IS ";DX:PRINT:GOSUB 3280
  245. 2350  IF O$<>"A" THEN 2480
  246. 2360  IF WV=0 THEN PRINT:PRINT"** POUNDING ON ";C$(12+A);" WON'T HURT IT":GOTO 2690
  247. 2370  IF BF=1 THEN PRINT:PRINT"YOU CAN'T BEAT IT TO DEATH WITH A BOOK":GOTO 2690
  248. 2380  IF DX<FNA(20)+(BL*3) THEN PRINT:PRINT "  DRAT!  MISSED":GOTO 2690
  249. 2390  PRINT:PRINT"  YOU HIT THE LOUSY ";RIGHT$(C$(A+12),LEN(C$(A+12))-2):Q2=Q2-WV
  250. 2400  IF (A=9 OR A=12) AND FNA(8) =1 THEN PRINT:PRINT" OH NO!!  YOUR ";W$(WV+1);" BROKE":WV=0
  251. 2410  IF Q2>0 THEN 2690
  252. 2420  PRINT:MC=MC-1:PRINT C$(A+12);" LIES DEAD AT YOUR FEET": IF H>T-60 THEN 2440
  253. 2430  PRINT:PRINT"YOU SPEND AN HOUR EATING ";C$(A+12);E$(FNA(8)):H=T
  254. 2440  IF X<>R(1) OR Y<>R(2) OR Z<>R(3) THEN ON 1-(A=13) GOTO 2460,3220
  255. 2450  PRINT:PRINT"GREAT ZOT!  YOU'VE FOUND THE RUNESTAFF":R(1)=0:RF=1
  256. 2460  Q=FNA(1000):PRINT:PRINT"YOU NOW GET HIS HOARD OF ";Q;" GP'S"
  257. 2470  GP=GP+Q:GOTO 1420
  258. 2480  IF O$="R" THEN 2690
  259. 2490  IF (O$<>"C") THEN 2610
  260. 2500  IF IQ<15 OR Q3>1 THEN PRINT:PRINT" YOU CAN"T CAST A SPELL NOW!":GOTO 2320
  261. 2510  PRINT:PRINT "WHICH SPELL (WEB, FIREBALL, OR DEATHSPELL) ";:GOSUB 3290:PRINT
  262. 2520  IF O$<>"W" THEN 2540
  263. 2530  ST=ST-1:WC=FNA(8)+1:ON 1-(ST<1) GOTO 2690,2840
  264. 2540  IF O$<>"F" THEN 2580
  265. 2550  Q=FNA(7)+FNA(7):ST=ST-1:IQ=IQ-1:IF(IQ<1) OR (ST<1) THEN 2840
  266. 2560  PRINT "   IT DOES ";Q;" POINTS OF DAMAGE.":PRINT
  267. 2570  Q2=Q2-Q:GOTO 2410
  268. 2580  IF O$<>"D" THEN PRINT:PRINT"** TRY ONE OF THE OPTIONS GIVEN!":GOTO 2320
  269. 2590  PRINT "DEATH - - - ";:IF IQ<15+FNA(4) THEN PRINT "YOURS":IQ=0:GOTO 2840
  270. 2600  PRINT "HIS":PRINT:Q2=0:GOTO 2420
  271. 2610  IF O$<>"B" OR Q3>1 THEN PRINT:PRINT"** CHOOSE ONE OF THE LISTED OPTIONS":GOTO 2320
  272. 2620  IF TC=0  THEN PRINT:PRINT"`ALL I WANT IS YOUR LIFE!'":GOTO 2690
  273. 2630  Q=FNA(8):IF T(Q)=0 THEN 2630
  274. 2640  PRINT:PRINT" I WANT ";C$(Q+25);", WILL YOU GIVE IT TO ME ";
  275. 2650  GOSUB 3290:IF O$="N" THEN 2690
  276. 2660  IF O$<>"Y" THEN PRINT Y$:GOTO 2640
  277. 2670  T(Q)=0:TC=TC-1:PRINT:PRINT "OK, JUST DON'T TELL ANYONE"
  278. 2680  VF=VF+(PEEK(FND(Z))=25):GOTO 620
  279. 2690  Q3=2:IF WC>0 THEN WC=WC-1:IF WC=0 THEN PRINT:PRINT"THE WEB JUST BROKE!"
  280. 2700  Z$=RIGHT$(C$(12+A),LEN(C$(12+A))-2):IF WC<=0 THEN 2720
  281. 2710  PRINT:PRINT "THE ";Z$;" IS STUCK AND CAN'T ATTACK":GOTO 2750
  282. 2720  PRINT:PRINT "THE ";Z$;" ATTACKS":IF DX<FNA(7)+FNA(7)+FNA(7)+BL*3 THEN 2740
  283. 2730  PRINT:PRINT"  HAH!  HE MISSED YOU":GOTO 2750
  284. 2740  PRINT:PRINT"  OUCH! HE HIT YOU":Q=Q1:GOSUB 2800:IF ST<1 THEN 2840
  285. 2750  IF O$<>"R" THEN 2320
  286. 2760  PRINT:PRINT"YOU HAVE ESCAPED":PRINT
  287. 2770  PRINT"DO YOU GO NORTH, SOUTH, EAST, OR WEST ";:GOSUB 3290
  288. 2780  IF (O$="N") OR (O$="S") OR (O$="E") OR (O$="W") THEN 950
  289. 2790  PRINT:PRINT "DON'T PRESS YOUR LUCK ";R$(RC):PRINT:GOTO 2770
  290. 2800  IF AV=0 THEN 2830
  291. 2810  Q=Q-AV:AH=AH-AV:IF Q<0 THEN AH=AH-Q:Q=0
  292. 2820  IF AH<0 THEN AH=0:AV=0:PRINT:PRINT"YOUR ARMOR IS DESTROYED - GOOD LUCK!"
  293. 2830  ST=ST-Q:RETURN
  294. 2840  FOR Q=1 TO 750:NEXT Q:PRINT CHR$(12):GOSUB 3270
  295. 2850  PRINT "A NOBLE EFFORT, OH FORMERLY LIVING ";R$(RC):PRINT
  296. 2860  PRINT "YOU DIED FROM A LACK OF ";:IF ST<1 THEN PRINT "STRENGTH"
  297. 2870  IF IQ<1 THEN PRINT "INTELLIGNECE"
  298. 2880  IF DX<1 THEN PRINT "DEXTERITY"
  299. 2890  PRINT:PRINT:Q3=1:PRINT"WHEN YOU DIED YOU HAD:":PRINT:GOTO 2970
  300. 2900  Q3=0:PRINT:PRINT "YOU LEFT THE CASTLE WITH";:IF OF=0 THEN PRINT "OUT";
  301. 2910  PRINT "  THE ORB OF ZOT":PRINT:IF OF=0 THEN 2940
  302. 2920  PRINT:PRINT "A GLORIOUS VICTORY!":PRINT
  303. 2930  PRINT "YOU ALSO GOT OUT WITH THE FOLLOWING:":PRINT:GOTO 2960
  304. 2940  PRINT "A LESS THAN AWE-INSPIRING DEFEAT."
  305. 2950  PRINT:PRINT "WHEN YOU LEFT THE CASTLE YOU HAD:":PRINT
  306. 2960  IF Q3=0 THEN PRINT "YOUR MISERABLE LIFE"
  307. 2970  FOR Q=1 TO 8:IF T(Q)=1 THEN PRINT C$(Q+25)
  308. 2980  NEXT Q:PRINT W$(WV+1):PRINT W$(AV+5):IF LF=1 THEN PRINT "A LAMP"
  309. 2990  PRINT FL; "FLARES":PRINT GP;"GOLD PIECES":IF RF=1 THEN PRINT "THE RUNESTAFF"
  310. 3000  PRINT:PRINT"AND IT TOOK YOU ";T;" TURNS!":PRINT
  311. 3010  PRINT:PRINT:PRINT"PLAY AGAIN ";:GOSUB 3290:PRINT
  312. 3020  IF O$="Y" THEN PRINT "SOME ";R$(RC);"S NEVER LEARN":PRINT:PRINT:GOTO 80
  313. 3030  IF O$<>"N" THEN PRINT Y$:GOTO 3010
  314. 3040  PRINT "MAYBE DUMB ";R$(RC);" NOT SO DUMB AFTER ALL":PRINT:END
  315. 3050  PRINT:PRINT "GREAT UNMITIGATED ZOT!":PRINT
  316. 3060  PRINT "YOU JUST FOUND THE ORB OF ZOT":PRINT
  317. 3070  PRINT "THE RUNESTAFF IS GONE":RF=0:OF=1:O(1)=0:GOTO 1420
  318. 3080  DATA AN EMPTY ROOM,.,THE ENTRANCE,E,STAIRS GOING UP,U
  319. 3090  DATA STAIRS GOING DOWN,D,A POOL,P,A CHEST,C,GOLD PIECES,G
  320. 3100  DATA FLARES,F,A WARP,W,A SINKHOLE,S,A CRYSTAL ORB,O
  321. 3110  DATA A BOOK,B,A KOBOLD,M,AN ORC,M,A WOLF,M,A GOBLIN,M,AN OGRE,M
  322. 3120  DATA A TROLL,M,A BEAR,M,A MINOTAUR,M,A GARGOYLE,M,A CHIMERA,M
  323. 3130  DATA A BALROG,M,A DRAGON,M,A VENDOR,V,THE RUBY RED,T
  324. 3140  DATA THE NORN STONE,T,THE PALE PEARL,T,THE OPAL EYE,T
  325. 3150  DATA THE GREEN GEM,T,THE BLUE FLAME,T,THE PALANTIR,T,THE SILMARIL,T
  326. 3160  DATA X,"?",NO WEAPON,WICH
  327. 3170  DATA DAGGER," STEW",MACE," SOUP",SWORD," BURGER",NO ARMOR," ROAST"
  328. 3180  DATA LEATHER," MUNCHY",CHAINMAIL," TACO",PLATE," PIE"
  329. 3190  DATA HOBBIT,ELF,MAN,DWARF,LOUSY,FAIR,GOOD,EXCELLENT,T,I,A,L,I,Z,I,N," ",C,A
  330. 3200  X=FNA(8):Y=FNA(8):IF PEEK(FND(Z))<>101 THEN 3200
  331. 3210  POKE FND(Z),Q:RETURN
  332. 3220  PRINT:PRINT"YOU GET ALL HIS WARES:":PRINT:PRINT"PLATE ARMOR":AV=3:AH=21
  333. 3230  PRINT "A SWORD":WV=3:PRINT"A STRENGTH POTION":ST=FNC(ST+FNA(8))
  334. 3240  PRINT "AN INTELLIGENCE POTION":IQ=FNC(IQ+FNA(6))
  335. 3250  PRINT "A DEXTERITY POTION":DX=FNC(DX+FNA(6)):IF LF=0 THEN PRINT "A LAMP":LF=1
  336. 3260  GOTO 2460
  337. 3270  FOR Q=1 TO 80:PRINT "*";:NEXT Q:PRINT:PRINT:RETURN
  338. 3280  PRINT:PRINT"YOUR CHOICE ";
  339. 3290  INPUT O$:IF O$="" THEN GOSUB 3333:GOTO 3290:ELSE O$=LEFT$(O$,1):IF ASC(O$)>90 THEN O$=CHR$(ASC(O$)-32)
  340. 3295  RETURN
  341. 3300  PRINT
  342. 3303  PRINT "YOU HAVE ";OT;" POINTS LEFT TO ALLOCATE."
  343. 3305  PRINT"HOW MANY POINTS DO YOU ADD TO ";Z$;:INPUT O$:IF O$="" THEN PRINT:GOSUB 3333:GOTO 3303
  344. 3310  Q=VAL(O$):IF (Q=0) AND (ASC(O$)<>48) THEN Q=-1
  345. 3320  IF (Q<0)OR(Q>OT)OR(Q<>INT(Q))THEN PRINT:PRINT "STUPID ";R$(RC);", ";:GOTO 3303
  346. 3330  OT=OT-Q:RETURN
  347. 3333  PRINT "ANSWER THE QUESTION, STUPID ";R$(RC);"!":RETURN
  348. 3350  PRINT:PRINT Z$;:INPUT O$:IF O$="" THEN PRINT:GOSUB 3333: GOTO 3350: ELSE Q=INT(VAL(O$)):IF (Q>0) AND (Q<9) THEN RETURN
  349. 3360  PRINT:PRINT"** TRY A NUMBER FROM 1 TO 8, DUMMY!":GOTO 3350
  350. 3370  PRINT:PRINT"WANT TO BUY A POTION OF ";Z$;" FOR 1000 GP'S ";:GOTO 3290
  351. 3380  PRINT:PRINT"YOUR ";Z$;" IS NOW ";Q:RETURN
  352. 3390  PRINT "HERE IS A LIST OF ";Z$;" YOU CAN BUY (WITH COST IN <>)":PRINT:RETURN
  353. 3400  PRINT "YOU ARE AT (";X;",";Y;") LEVEL ";Z:RETURN
  354. 4000  CLS:PRINT "     HERE IS THE LIST OF COMMANDS:"
  355. 4005  PRINT"(TO SAVE TIME, JUST TYPE THE 1ST LETTER)"
  356. 4010  PRINT
  357. 4020  PRINT "NORTH"
  358. 4030  PRINT "SOUTH"
  359. 4040  PRINT "EAST"
  360. 4050  PRINT "WEST"
  361. 4060  PRINT "UP    - YOU MUST BE AT A STAIRWAY"
  362. 4070  PRINT "DOWN  - YOU MUST BE AT A STAIRWAY"
  363. 4080  PRINT "MAP   - YOUR POSITION INDICATED BY <>"
  364. 4100  PRINT "FLARE - ILLUMINATE 4 ADJOINING ROOMS"
  365. 4110  PRINT "LIGHT - LOOK INTO AN ADJOINING ROOM"
  366. 4130  PRINT "OPEN  - A BOOK OR CHEST"
  367. 4135  PRINT "DRINK - FROM A POOL"
  368. 4136  PRINT "        ( ABBREVIATED ";CHR$(34);"DR";CHR$(34);" )"
  369. 4140  PRINT "GAZE  - INTO AN ORB"
  370. 4150  PRINT "TELEPORT - THE RUNESTAFF IS REQUIRED"
  371. 4155  PRINT "HELP  - OR "CHR$(34);"?";CHR$(34)
  372. 4160  PRINT "QUIT  - WHEN YOU WANT TO CHICKEN OUT!"
  373. 4170  PRINT:INPUT "***  HIT ENTER TO CONTINUE  ***",O$:RETURN
  374. 4180  PRINT "       ABBREVIATIONS OF ASSETS:"
  375. 4190  PRINT CHR$(34);"ST";CHR$(34);" = STRENGTH; ";CHR$(34);"IQ";CHR$(34);" = INTELLIGENCE;"
  376. 4200  PRINT CHR$(34);"DX";CHR$(34);" = DEXTERITY; ";CHR$(34);"GP'S";CHR$(34);" = GOLD PIECES;"
  377. 4210  PRINT:INPUT "***  HIT ENTER TO CONTINUE  ***",O$:RETURN
  378. 4220  CLS:PRINT"YOUR QUEST IS TO EXPLORE THE WIZARD'S CASTLE AND"
  379. 4230  PRINT"GET OUT ALIVE WITH THE FABULOUS, PRICELESS ORB OF"
  380. 4240  PRINT"ZOT. LEGEND HAS IT THAT THERE ARE MANY OTHER"
  381. 4250  PRINT"VALUABLE TREASURES, SOME WITH MAGICAL PROPERTIES,"
  382. 4260  PRINT"THAT CAN HELP YOU THROUGH THE DIFFICULTIES YOU"
  383. 4270  PRINT"WILL ENCOUNTER IN THE CASTLE. THERE ARE ALSO"
  384. 4275  PRINT"COUNTLESS PIECES OF GOLD TO ADD TO YOUR PLUNDER"
  385. 4276  PRINT"OR BE USED TO BUY YOUR WAY OUT OF TROUBLE."
  386. 4278  PRINT
  387. 4280  PRINT"BEFORE HE MYSTERIOUSLY DISAPPEARED, THE"
  388. 4290  PRINT"WIZARD INSTALLED MANY SAFEGUARDS AND TRAPS FOR"
  389. 4300  PRINT"THE CARELESS AND FOOLHARDY EXPLORERS THAT MIGHT"
  390. 4310  PRINT"ATTEMPT TO PILLAGE HIS CASTLE. ALSO, MANY MONSTERS"
  391. 4320  PRINT"NOW MAKE THEIR HOME IN THE CASTLE LABYRINTHS; SO"
  392. 4330  PRINT"BE CAREFUL WHERE YOU VENTURE."
  393. 4350  PRINT
  394. 4360  PRINT"I AM PREPARED TO OFFER EXTENSIVE INFORMATION ABOUT"
  395. 4370  PRINT"THE CASTLE PIECED TOGETHER FROM TALES OF OTHER"
  396. 4380  PRINT"ADVENTURERS THAT BRAVED THE DANGERS OF THE WIZARD'S"
  397. 4390  PRINT"CASTLE AND LIVED TO TELL ABOUT IT. ASK FOR HELP"
  398. 4400  PRINT"ANYTIME AFTER YOUR EXPLORATION BEGINS."
  399. 4410  PRINT:INPUT "*** HIT ENTER TO CONTINUE ***",O$:RETURN
  400. 4500  CLS:PRINT "MAP AND FLARE ABBREVIATIONS:":PRINT
  401. 4510  PRINT "  ?  =  UNEXPLORED ROOM"
  402. 4520  PRINT "  .  =  EMPTY ROOM"
  403. 4530  PRINT "  B  =  BOOK"
  404. 4540  PRINT "  C  =  CHEST"
  405. 4550  PRINT "  D  =  STAIRS DOWN"
  406. 4560  PRINT "  E  =  ENTRANCE"
  407. 4570  PRINT "  F  =  FLARES"
  408. 4580  PRINT "  G  =  GOLD"
  409. 4590  PRINT "  M  =  MONSTER"
  410. 4600  PRINT "  O  =  ORB"
  411. 4610  PRINT "  P  =  POOL"
  412. 4620  PRINT "  S  =  SINKHOLE"
  413. 4630  PRINT "  T  =  TREASURE"
  414. 4640  PRINT "  U  =  STAIRS UP"
  415. 4650  PRINT "  V  =  VENDOR"
  416. 4660  PRINT "  W  =  WARP"
  417. 4670  PRINT:INPUT "***  HIT ENTER TO RETURN  ***",O$:RETURN
  418. 4900  PRINT:PRINT "OPTION ";O$;" NOT YET IMPLEMENTED"
  419. 4910  PRINT:INPUT "***  HIT ENTER TO RETURN  ***",O$:RETURN
  420. 5000  CLS:PRINT "HELP MENU:  (JUST TYPE THE FIRST CHARACTER)"
  421. 5010  PRINT
  422. 5020  PRINT "    INTRODUCTION"
  423. 5025  PRINT "    COMMANDS"
  424. 5030  PRINT "    DESCRIPTION OF THE CASTLE"
  425. 5040  PRINT "    FLARE & MAP ABBREVIATIONS"
  426. 5050  PRINT "    RUNESTAFF"
  427. 5060  PRINT "    ORB OF ZOT"
  428. 5070  PRINT "    VENDORS"
  429. 5080  PRINT "    MONSTERS"
  430. 5085  PRINT "    TREASURES"
  431. 5090  PRINT "    BOOKS, CHESTS, POOLS, & CRYSTAL ORBS"
  432. 5110  PRINT
  433. 5120  PRINT "*** HIT ENTER TO RESUME EXECUTION ***":INPUT "",O$
  434. 5130  IF O$="" THEN RETURN
  435. 5140  O$=LEFT$(O$,1):IF ASC(O$)>90 THEN O$=CHR$(ASC(O$)-32)
  436. 5150  IF O$="C" THEN GOSUB 4000: GOTO 5000
  437. 5151  IF O$="B" THEN GOSUB 5500: GOTO 5000
  438. 5152  IF O$="O" THEN GOSUB 5700: GOTO 5000
  439. 5153  IF O$="R" THEN GOSUB 5900: GOTO 5000
  440. 5154  IF O$="D" THEN GOSUB 6000: GOTO 5000
  441. 5155  IF O$="T" THEN GOSUB 6200: GOTO 5000
  442. 5156  IF O$="V" THEN GOSUB 6300: GOTO 5000
  443. 5157  IF O$="M" THEN GOSUB 6500: GOTO 5000
  444. 5160  IF O$="I" THEN GOSUB 4220: GOTO 5000
  445. 5170  IF O$="F" THEN GOSUB 4500: GOTO 5000
  446. 5180  GOSUB 4900:GOTO 5000
  447. 5500  CLS:PRINT "OTHER CASTLE FEATURES:":PRINT
  448. 5510  PRINT "BOOKS AND CHESTS MAY BE OPENED OR IGNORED."
  449. 5520  PRINT "IF OPENED, THE CONTENTS MAY HELP YOU, DO"
  450. 5530  PRINT "YOU HARM, OR HAVE NO EFFECT. AFTER BEING"
  451. 5540  PRINT "OPENED, A BOOK OR CHEST DISAPPEARS.":PRINT
  452. 5550  PRINT "YOU MAY DRINK FROM A POOL ANY NUMBER OF"
  453. 5560  PRINT "TIMES WITH RANDOM RESULTS - SOME HELPFUL,"
  454. 5570  PRINT "SOME HARMFUL.":PRINT
  455. 5580  PRINT "YOU MAY GAZE INTO A CRYSTAL ORB ANY NUMBER"
  456. 5590  PRINT "OF TIMES WITH RANDOM RESULTS. THE ORB CAN GIVE"
  457. 5600  PRINT "YOU VALUABLE INFORMATION ABOUT THE LOCATION OF"
  458. 5610  PRINT "THINGS IN THE CASTLE. BUT SOMETIMES IT LIES!"
  459. 5620  PRINT "SOME GAZES CAN DO YOU HARM.":PRINT
  460. 5630  INPUT"*** HIT ENTER TO RETURN TO MENU ***",O$:RETURN
  461. 5700  CLS:PRINT "ORB OF ZOT:":PRINT
  462. 5710  PRINT "LEGEND HAS IT THAT THE WIZARD SECRETED THE "
  463. 5720  PRINT "FABULOUS ORB IN A ROOM WITH UNPREDICTABLE"
  464. 5730  PRINT "MOVEMENT PROPERTIES. YOU'LL NEVER FIND THE ORB"
  465. 5740  PRINT "BY VISITING THE ROOM IN ANY NORMAL MOVE; YOU"
  466. 5750  PRINT "MUST TELEPORT INTO THE ROOM (AFTER SECURING THE"
  467. 5760  PRINT "THE RUNESTAFF) TO RELEASE THE ORB FROM THE"
  468. 5770  PRINT "WIZARD'S SPELL.":PRINT
  469. 5780  PRINT "SOMTIMES A CRYSTAL ORB CAN HELP LOCATE THE"
  470. 5790  PRINT "ORB OF ZOT.":PRINT
  471. 5800  INPUT"*** HIT ENTER TO RETURN TO MENU ***",O$:RETURN
  472. 5900  CLS:PRINT "RUNESTAFF:":PRINT
  473. 5903  PRINT "THE RUNESTAFF IS GUARDED BY ONE OF THE MONSTERS"
  474. 5904  PRINT "IN THE CASTLE. YOU MUST KILL THE MONSTER TO GET"
  475. 5905  PRINT "THE RUNESTAFF FROM IT. WHICH MONSTER YOU ASK?"
  476. 5906  PRINT "THAT'S FOR ME TO KNOW AND YOU TO FIND OUT!":PRINT
  477. 5910  PRINT "THE RUNESTAFF ALLOWS THE ADVENTURER TO TELEPORT"
  478. 5920  PRINT "(BE INSTANTLY TRANSPORTED) TO ANY ROOM OF HIS"
  479. 5930  PRINT "CHOOSING. TELEPORTING INTO THE ROOM CONTAINING"
  480. 5940  PRINT "THE ORB OF ZOT IS THE ONLY WAY TO ACQUIRE IT;"
  481. 5950  PRINT "HOWEVER, AFTER THE ORB OF ZOT IS ACQUIRED, THE"
  482. 5960  PRINT "RUNESTAFF DISAPPEARS.":PRINT
  483. 5970  INPUT"*** HIT ENTER TO RETURN TO MENU ***",O$:RETURN
  484. 6000  CLS:PRINT "MOVING AROUND THE CASTLE:":PRINT
  485. 6010  PRINT "THE CASTLE IS COMPOSED OF 8 LEVELS OF 64 ROOMS EACH. THE ROOMS OF EACH LEVEL"
  486. 6020  PRINT "ARE ARRANGED IN AN 8 X 8 MATRIX. THE COLUMNS, ROWS, AND LEVELS ARE CIRCULAR;"
  487. 6030  PRINT "FOR EXAMPLE, GOING SOUTH FROM THE SOUTHERN-MOST ROOM (8) OF A COLUMN WILL"
  488. 6040  PRINT "RESULT IN THE EXPLORER ENTERING THE NORTHERN-MOST ROOM (1) OF THE COLUMN."
  489. 6060  PRINT "THE SAME HOLDS TRUE FOR EAST TO WEST (ROW) MOVEMENT. A SINKHOLE ON THE LAST"
  490. 6080  PRINT "LEVEL (8) MOVES EXPLORER TO THE FIRST LEVEL (1). THE ONLY EXCEPTION TO THIS"
  491. 6090  PRINT "CIRCULAR MOVEMENT IS GOING NORTH FROM THE ENTRANCE ROOM - YOU'LL LEAVE THE"
  492. 6100  PRINT "CASTLE!":PRINT
  493. 6110  PRINT "MOST MOVEMENT IS ACCOMPLISHED USING THE COMMANDS NORTH, SOUTH, EAST, AND WEST."
  494. 6120  PRINT "AT STAIRWAYS, THE EXPLORER CAN GO UP OR DOWN TO THE NEXT LEVEL.":PRINT
  495. 6140  PRINT "IF THE EXPLORER ENTERS A SINKHOLE, HE FALLS TO THE NEXT LEVEL AT THE SAME ROW"
  496. 6150  PRINT "AND COLUMN.":PRINT
  497. 6160  PRINT "A WARP INSTANTLY TRANSPORTS AN EXPLORER TO SOME ROOM IN THE CASTLE AT RANDOM.":PRINT
  498. 6181  PRINT "IF THE EXPLORER HAS THE RUNESTAFF, HE CAN TELEPORT TO ANY ROOM IN THE CASTLE"
  499. 6182  PRINT "HE SELECTS.":PRINT
  500. 6190  INPUT"*** HIT ENTER TO RETURN TO MENU ***",O$:RETURN
  501. 6200  CLS:PRINT "TREASURES:     (LISTED IN ORDER ACCORDING TO WORTH, FROM LEAST TO GREATEST)":PRINT
  502. 6210  FOR III=1 TO 8:PRINT"   ";C$(III+25):NEXT:PRINT:PRINT
  503. 6220  PRINT "THE OPAL EYE CAN CURE BLINDNESS.":PRINT
  504. 6230  PRINT "THE BLUE FLAME CAN RESOLVE DIFFICULTIES WITH BOOKS.":PRINT
  505. 6240  INPUT"*** HIT ENTER TO RETURN TO MENU ***",O$:RETURN
  506. 6300  CLS:PRINT "VENDORS:":PRINT
  507. 6310  PRINT "WHEN A VENDOR IS ENCOUNTERED, YOU MAY DECIDE TO IGNORE, TRADE WITH, OR ATTACK"
  508. 6320  PRINT "HIM.":PRINT
  509. 6330  PRINT "IF YOU ELECT TO IGNORE HIM, NOTHING HAPPENS.":PRINT
  510. 6340  PRINT "ATTACKING A VENDOR CAN BE HAZARDOUS TO YOUR HEALTH. A VENDOR IS THE STRONGEST"
  511. 6350  PRINT "OPPONENT IN THE CASTLE (SEE ";CHR$(34);"COMBAT";CHR$(34);"). ALSO, AFTER ATTACKING A VENDOR,"
  512. 6360  PRINT "ANY OTHER VENDOR YOU ENCOUNTER WILL IMMEDIATELY ATTACK YOU [UNTIL YOU BRIBE"
  513. 6370  PRINT "A VENDOR WITH A TREASURE (SEE ";CHR$(34);"COMBAT";CHR$(34);")]. BUT IF YOU DEFEAT THE VENDOR, THE"
  514. 6380  PRINT "SPOILS CAN BE ENORMOUS IN TERMS OF ARMOR, WEAPONS, STRENGTH, ETC.":PRINT
  515. 6390  PRINT "IF YOU ELECT TO TRADE WITH THE VENDOR, HE WILL OFFER YOU GOLD FOR ANY TREASURES"
  516. 6400  PRINT "YOU POSSESS. THEN, IF YOU HAVE AT LEAST 1000 GOLD PIECES, HE WILL OFFER VARIOUS"
  517. 6410  PRINT "WARES FOR SALE.":PRINT
  518. 6420  INPUT"*** HIT ENTER TO RETURN TO MENU ***",O$:RETURN
  519. 6500  CLS:PRINT "MONSTERS:":PRINT "(YOUR OPPONENTS ARE LISTED IN ORDER OF STRENGTH, FROM LEAST TO GREATEST)":PRINT
  520. 6510  FOR III=1 TO 13:PRINT "   ";C$(III+12):NEXT:PRINT
  521. 6520  PRINT "YOU CAN BRIBE A MONSTER IF YOU HAVE ANY TREASURE HE WANTS."
  522. 6530  PRINT "YOU CAN CAST A SPELL IF YOU HAVE SUFFICIENT IQ (GREATER THAN 14)."
  523. 6540  PRINT "YOUR ARMOR AND STRENGTH MUST WITHSTAND THE BLOWS OF THE MONSTER; IF YOUR"
  524. 6550  PRINT "STRENGTH IS EXHAUSTED, YOU WILL BE DEAD."
  525. 6560  PRINT "THE ACCUMULATIVE DAMAGE FROM THE BLOWS OF YOUR WEAPON CAN KILL THE MONSTER.":PRINT
  526. 6570  INPUT"*** HIT ENTER TO RETURN TO MENU ***",O$:RETURN
  527.